[v1.0.0] initial module implementation

Author: bryan-rhm

README.md

@@ -0,0 +1,37 @@
+# Terraform ECS Task Definition Module
+
+## Requirements
+
+| Name | Version |
+|------|---------|
+| <a name="requirement_terraform"></a> [terraform](#requirement\_terraform) | >= 1.0.0 |
+| <a name="requirement_aws"></a> [aws](#requirement\_aws) | >= 3.43.0 |
+
+
+## Resources
+
+| Name | Type |
+|------|------|
+| [aws_ecs_task_definition.this](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/ecs_task_definition) | resource |
+
+## Inputs
+
+| Name | Description | Type | Default | Required |
+|------|-------------|------|---------|:--------:|
+| <a name="input_container_definitions"></a> [container\_definitions](#input\_container\_definitions) | A list of valid container definitions provided as a single valid JSON document. | `string` | n/a | yes |
+| <a name="input_name"></a> [name](#input\_name) | A unique name for your task definition. | `string` | n/a | yes |
+| <a name="input_placement_constraints"></a> [placement\_constraints](#input\_placement\_constraints) | (Optional) Configuration block for rules that are taken into consideration during task placement. Maximum number of placement\_constraints is 10. This is a list of maps, where each map should contain "type" and "expression". | `list(any)` | `[]` | no |
+| <a name="input_proxy_configuration"></a> [proxy\_configuration](#input\_proxy\_configuration) | (Optional) Configuration block for the App Mesh proxy. | `list(any)` | `[]` | no |
+| <a name="input_requires_compatibilities"></a> [requires\_compatibilities](#input\_requires\_compatibilities) | Set of launch types required by the task. The valid values are EC2 and FARGATE. | `list` | <pre>[<br>  "FARGATE"<br>]</pre> | no |
+| <a name="input_tags"></a> [tags](#input\_tags) | (Optional) Key-value map of resource tags. | `map(string)` | `{}` | no |
+| <a name="input_task_cpu"></a> [task\_cpu](#input\_task\_cpu) | (Optional) Number of cpu units used by the task. If the requires\_compatibilities is FARGATE this field is required. | `number` | `null` | no |
+| <a name="input_task_execution_role"></a> [task\_execution\_role](#input\_task\_execution\_role) | (Optional) ARN of the task execution role that the Amazon ECS container agent and the Docker daemon can assume. | `string` | `null` | no |
+| <a name="input_task_memory"></a> [task\_memory](#input\_task\_memory) | (Optional) Amount (in MiB) of memory used by the task. If the requires\_compatibilities is FARGATE this field is required. | `number` | `null` | no |
+| <a name="input_task_role_arn"></a> [task\_role\_arn](#input\_task\_role\_arn) | (Optional) ARN of IAM role that allows your Amazon ECS container task to make calls to other AWS services. | `string` | `null` | no |
+| <a name="input_volumes"></a> [volumes](#input\_volumes) | (Optional) Configuration block for volumes that containers in your task may use. | <pre>list(object({<br>    host_path = string<br>    name      = string<br>    docker_volume_configuration = list(object({<br>      autoprovision = bool<br>      driver        = string<br>      driver_opts   = map(string)<br>      labels        = map(string)<br>      scope         = string<br>    }))<br>    efs_volume_configuration = list(object({<br>      file_system_id          = string<br>      root_directory          = string<br>      transit_encryption      = string<br>      transit_encryption_port = string<br>      authorization_config = list(object({<br>        access_point_id = string<br>        iam             = string<br>      }))<br>    }))<br>  }))</pre> | `[]` | no |
+
+## Outputs
+
+| Name | Description |
+|------|-------------|
+| <a name="output_output"></a> [output](#output\_output) | Task definition attributes |

main.tf

@@ -0,0 +1,66 @@
+resource "aws_ecs_task_definition" "this" {
+  cpu                      = var.task_cpu
+  memory                   = var.task_memory
+  family                   = var.name
+  network_mode             = var.network_mode
+  task_role_arn            = var.task_role_arn
+  execution_role_arn       = var.task_execution_role
+  container_definitions    = var.container_definitions
+  requires_compatibilities = var.requires_compatibilities
+  
+  dynamic "placement_constraints" {
+    for_each = var.placement_constraints
+    content {
+      expression = try(placement_constraints.value.expression, null)
+      type       = placement_constraints.value.type
+    }
+  }
+
+  dynamic "proxy_configuration" {
+    for_each = var.proxy_configuration
+    content {
+      container_name = proxy_configuration.value.container_name
+      properties     = try(proxy_configuration.value.properties, null)
+      type           = try(proxy_configuration.value.type, null)
+    }
+  }
+  
+  dynamic "volume" {
+    for_each = var.volumes
+    content {
+      name = volume.value.name
+
+      host_path = lookup(volume.value, "host_path", null)
+
+      dynamic "docker_volume_configuration" {
+        for_each = lookup(volume.value, "docker_volume_configuration", [])
+        content {
+          autoprovision = lookup(docker_volume_configuration.value, "autoprovision", null)
+          driver        = lookup(docker_volume_configuration.value, "driver", null)
+          driver_opts   = lookup(docker_volume_configuration.value, "driver_opts", null)
+          labels        = lookup(docker_volume_configuration.value, "labels", null)
+          scope         = lookup(docker_volume_configuration.value, "scope", null)
+        }
+      }
+
+      dynamic "efs_volume_configuration" {
+        for_each = lookup(volume.value, "efs_volume_configuration", [])
+        content {
+          file_system_id          = lookup(efs_volume_configuration.value, "file_system_id", null)
+          root_directory          = lookup(efs_volume_configuration.value, "root_directory", null)
+          transit_encryption      = lookup(efs_volume_configuration.value, "transit_encryption", null)
+          transit_encryption_port = lookup(efs_volume_configuration.value, "transit_encryption_port", null)
+          dynamic "authorization_config" {
+            for_each = lookup(efs_volume_configuration.value, "authorization_config", [])
+            content {
+              access_point_id = lookup(authorization_config.value, "access_point_id", null)
+              iam             = lookup(authorization_config.value, "iam", null)
+            }
+          }
+        }
+      }
+    }
+  }
+
+  tags = var.tags
+}

outputs.tf

@@ -0,0 +1,4 @@
+output "output" {
+  description = "Task definition attributes"
+  value       = aws_ecs_task_definition.this
+}

variables.tf

@@ -0,0 +1,93 @@
+variable "name" {
+  description = "A unique name for your task definition."
+  type        = string
+}
+
+variable "container_definitions" {
+  description = "A list of valid container definitions provided as a single valid JSON document."
+  type        = string
+}
+
+variable "tags" {
+  description = "(Optional) Key-value map of resource tags."
+  type        = map(string)
+  default     = {}
+}
+
+#------------------------------------------------------------------------------
+# AWS ECS Task Definition Variables
+#------------------------------------------------------------------------------
+variable "task_role_arn" {
+  description = "(Optional) ARN of IAM role that allows your Amazon ECS container task to make calls to other AWS services."
+  type        = string
+  default     = null
+}
+
+variable "task_execution_role" {
+  description = "(Optional) ARN of the task execution role that the Amazon ECS container agent and the Docker daemon can assume."
+  type        = string
+  default     = null
+}
+
+variable "placement_constraints" {
+  description = "(Optional) Configuration block for rules that are taken into consideration during task placement. Maximum number of placement_constraints is 10. This is a list of maps, where each map should contain \"type\" and \"expression\"."
+  type        = list(any)
+  default     = []
+}
+
+variable "task_cpu" {
+  # https://docs.aws.amazon.com/AmazonECS/latest/developerguide/AWS_Fargate.html#fargate-task-defs
+  description = "(Optional) Number of cpu units used by the task. If the requires_compatibilities is FARGATE this field is required."
+  type        = number
+  default     = null
+}
+
+variable "task_memory" {
+  description = "(Optional) Amount (in MiB) of memory used by the task. If the requires_compatibilities is FARGATE this field is required."
+  type        = number
+  default     = null
+}
+
+variable "proxy_configuration" {
+  description = "(Optional) Configuration block for the App Mesh proxy."
+  type        = list(any)
+  default     = []
+}
+
+variable "volumes" {
+  description = "(Optional) Configuration block for volumes that containers in your task may use."
+  type = list(object({
+    host_path = string
+    name      = string
+    docker_volume_configuration = list(object({
+      autoprovision = bool
+      driver        = string
+      driver_opts   = map(string)
+      labels        = map(string)
+      scope         = string
+    }))
+    efs_volume_configuration = list(object({
+      file_system_id          = string
+      root_directory          = string
+      transit_encryption      = string
+      transit_encryption_port = string
+      authorization_config = list(object({
+        access_point_id = string
+        iam             = string
+      }))
+    }))
+  }))
+  default = []
+}
+
+variable "network_mode" {
+  description = "(Optional) Docker networking mode to use for the containers in the task. Valid values are none, bridge, awsvpc, and host."
+  type        = string
+  default     = "awsvpc"
+}
+
+variable "requires_compatibilities" {
+  description = "Set of launch types required by the task. The valid values are EC2 and FARGATE."
+  type        = list(string)
+  default     = ["FARGATE"]
+}

versions.tf

@@ -0,0 +1,10 @@
+terraform {
+  required_version = ">= 1.0.0"
+
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = ">= 3.43.0"
+    }
+  }
+}